Autofilter i excel skal medtage tomme celler under en værdi

Prøv at uploade et eksempel m/forklaring på det ønskede.

Eks:

AAA  Data
    Data
    Data
    Data
BBB  Data
    Data
    Data
    Data
CCC  Data
    osv
Jeg vil gerne have, at når man f.eks. vælger AAA i autofilter vises fra AAA plus de linjer med tomme celler indtil BBB.

Ok - vender tilbage

Er det kun i kolonne A det er relevant at anføre filter?

Hvad med at "udfylde" de tomme celler med en Makro?

Prøv i en kopi:

Ja det er kun i kolonne A der skal være filter

Vil gerne bibeholde de tomme felter

Skal du bruger de tomme celler?
Man kunne evt. lave tekst farven hvid, så indholdet ikke ses.

#7 ok

Ren VBA-filtrering
Anbring koden under det relevante ark
Send mail, hvis du vil have min model. @-adresse under min profil.

Dim antalRækker As Long, ræk As Long
Dim flag As Boolean
Private Sub CommandButton2_Click()
Dim Agrp
    Application.ScreenUpdating = False
   
    For ræk = 2 To antalRækker
        If Range("A" & ræk) <> "" Then
            Agrp = Range("A" & ræk)
            If erGrpValgt(Agrp) = True Then
                SkjulRækker ræk, False
            Else
                SkjulRækker ræk, True
            End If
        End If
    Next ræk
   
    UserForm1.Hide
End Sub
Private Sub SkjulRækker(fraRække, vis)
Dim r As Long
    Rows(fraRække & ":" & fraRække).Hidden = vis

    For r = fraRække + 1 To antalRækker
        If Cells(r, 1) = "" Then
            Rows(r & ":" & r).Hidden = vis
        Else
            Exit Sub
        End If
    Next r
End Sub
Private Function erGrpValgt(grp) As Boolean
Dim ix As Integer
    For ix = 0 To Me.ListBox1.ListCount - 1
        If grp = Me.ListBox1.List(ix) Then
            erGrpValgt = Me.ListBox1.Selected(ix)
            Exit Function
        End If
    Next ix
    erGrpValgt = False
End Function
Private Sub ListBox1_Change()
Dim ix As Integer, v0 As Boolean
    If ListBox1.ListIndex = 0 Then
        v0 = Me.ListBox1.Selected(0)
       
        If flag = False Then
            For ix = 1 To Me.ListBox1.ListCount - 1
                flag = True
                Me.ListBox1.Selected(ix) = v0
                flag = False
            Next ix
        End If
    Else
        Me.ListBox1.Selected(0) = False
    End If
End Sub
Private Sub UserForm_initialize()
Dim ix As Integer
    flag = False
   
    With ActiveWorkbook
        .Sheets(1).Activate
        antalRækker = ActiveCell.SpecialCells(xlLastCell).Row
    End With
   
    Me.ListBox1.Clear
   
    Me.ListBox1.AddItem "Alt"
   
    For ræk = 2 To antalRækker
        If Range("A" & ræk) <> "" Then
            Me.ListBox1.AddItem Range("A" & ræk)
        End If
    Next ræk
   
    For ix = 0 To Me.ListBox1.ListCount - 1
        Me.ListBox1.Selected(ix) = True
    Next ix
   
End Sub

NB: Dobbeltklik i A1 for at anvender VBA-filter.