Excel 97: Log-fil VBA

Smid dette ind i workbook'en

Public a As Date

Private Sub Workbook_BeforeClose(Cancel As Boolean)
b = Time()
c = a & " " & b
End Sub

Private Sub Workbook_Open()
a = Time()
End Sub

Kan du ikke blot erklære en global variabel, og så lægge starttidspunktet ind i denne ved opstart. Da den er global, kan din beforeclose-procedure jo også læse hvad der står i den.

jkrons
Det klarede du kun lidt hurtigere end jeg :-)  (men meget mere elegant)

Tak for hjælpen. Det var den globale variabel jeg havde glemt.

Lige en lille ting:
Der var en lille fejl i jkrons, så koden skal se sådan ud:

Public Start As Date

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Slut = Time()
Periode = Slut - Start
msg = Start & " " & Periode
End Sub

Private Sub Workbook_Open()
Start = Time()
End Sub

Imidlertid giver resultatet:
00:00:00 0,622858796296296
så det kunne se ud som om Start ikke virker rigtigt.
Derudover mangler der også lige lidt formatering.

Ok. Det virker godt nok hos mig. Bortset fra formateringen. Jeg troede det var de to tidspunkter du ville have vist. Derfor havde jeg ikke trukket dem fra hinanden.

Hvordan får jeg formateret Start til dd-mm-åååå tt:mm:ss og Periode til tt:mm:ss?

Med noget i retning af

Nystreng = Format(Start,"dd-mm-yyyy hh:nn:ss") & " " & Format(Periode,"hh:nn:ss")

eller hvad mener du?

Nu tror jeg, at jeg fangede den. Der skulle selvfølgelig have stået:

msg = Format(Start,"dd-mm-yyyy hh:nn:ss") & " " & Format(Periode,"hh:nn:ss")

Ja, det ser rigtigt ud, bortset fra nn = mm :-)
Men Time() må så skulle udskiftes med Now() for at få datoformatet ....

Ja, hvis du vil have dato med skal du bruge Now i stedet for Time.

nn er et fra mine Access erfaringer, hvor mm er måned og nn minutter. Jeg kan dog godt se, at Excel faktisk godt kan skelne - hvilket jo egentligt er lidt underligt :-)

Skal måske lige tilføje at nn faktisk også virker (men nn opfattes dog som minutter uanset hvor du skriver det).

superjap-> Det har også altid undret mig :-)

Ind imellem laver de åbenbart noget fornuftigt hos MS (der er måske lidt langt imellem, men de skal da have ros, når de fortjener det).

Fatter det ikke. Start sættes stadig til "0" så jeg får:
30-12-1899 00:00:00 15:28:01

Har du prøvet at skrive

Dim Start As Date

i stedet for Public

Njah - Public burde være rigtigt nok.

Kan man godt dimensionere et tidspunkt "Date"?

Ser ikke ud til, at der er noget som hedder "Time".

Det lyder spændende. Det findes hos mig. Har du prøvet med Now i stedet.

Begge findes hos mig, men det også bedst at bruge Now() - for det tifælde at du kommer over midnat.

Pladder! Jeg tror jeg misforstod. Time findes ikke ved dimensionering. Derfor bruge jeg Date.

:0)

Det var Time under Dim jeg mente - altså
Public Start As Time .....

:-)

Jeg har lige testet, og nedenstående virker på mit "apparat". Som kontrol har jeg blot indlagt nogen msgbokse. Det ser ud til at virke efter hensigten.


Public Start As Date

Private Sub Workbook_BeforeClose(Cancel As Boolean)

Slut = Now()
Periode = Slut - Start
msg = Start & " " & Periode
MsgBox (Format(Start, "dd-mm-yyyy hh:nn:ss") & " / " & Format(Periode, "hh:nn:ss"))

End Sub

Private Sub Workbook_Open()

Start = Now()
MsgBox (Format(Start, "dd-mm-yyyy hh:nn:ss"))

End Sub

Den kender ikke en Time datatype. Men date kan indeholde både dato og tid.

Trode måske Start var en "lukket" variabel, men det er heller ikke til tilfældet. Har prøvet at udskifte den med OpenTime.

I får lige hele koden:

Public OpenTime As Date

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    ' Skriver log-data til en tekstfil.
    ' Nye logs bliver tilføjet i bundet af filen.
    ' Hvis filen ikke eksisterer vil den blive oprettet.
    Dim iFileNumber      As Integer
    Dim msg              As String
    Dim strFileName      As String
    Dim OpenTime As Date
    Dim Slut As Date
    Dim Period As Date
       
    iFileNumber = FreeFile
    Slut = Now()
    Periode = Slut - OpenTime
    msg = Format(OpenTime, "dd-mm-yyyy hh:mm:ss") & " " & Format(Periode, "hh:mm:ss")
    strFileName = "C:\test.log"
    Open strFileName For Append Shared As #iFileNumber
    Print #iFileNumber, msg
    Close #iFileNumber
End Sub

Private Sub Workbook_Open()
    OpenTime = Now()
End Sub


Kan I få den til at virke?

Virker også hos mig.

Hmm, kører i Excel 97?

janvogt-> Nej, når jeg bruger din kode får jeg samme problem som dig. Mystisk?

Virker IKKE hos mig!

PROBLEM LØST ?

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    ' Skriver log-data til en tekstfil.
    ' Nye logs bliver tilføjet i bundet af filen.
    ' Hvis filen ikke eksisterer vil den blive oprettet.
    Dim iFileNumber      As Integer
    Dim msg              As String
    Dim strFileName      As String
    Dim Slut As Date
    Dim Period As Date
       
    iFileNumber = FreeFile
    Slut = Now()
    Periode = Slut - OpenTime
    msg = Format(OpenTime, "dd-mm-yyyy hh:mm:ss") & " " & Format(Periode, "hh:mm:ss")
    strFileName = "C:\test.log"
    Open strFileName For Append Shared As #iFileNumber
    Print #iFileNumber, msg
    Close #iFileNumber
End Sub

Private Sub Workbook_Open()
    OpenTime = Now()
End Sub

Problemet var at du erklærede OpenTime inde i beforeclose-sub'en og så bliver den jo nulstillet.  HOV-HOV!

Du erklærer din variabel to gange

superjap-> OK Der vsr du hurtigst og mest detaljeret. Man skal ikke skrive mens man arbejder med noget andet. Det nedsætter svartiden :-)

jkrons-> Nu snakker du ikke i telefon igen - vel!  :-)

Nope! Jeg skrive bare på en mindre afhandling ;-)

Pyha, så er den der :-)
Superjap, der var en lille fejl i din kode:
Dim Period As Date skal være Dim Periode As Date

Tak for hjælpen begge 2.
Hvis det er ok med jer deler I pointene for det fine samarbejde :-)

Det er da ok med mig. Tak for kampen!

Nu mangler jeg bare på én eller anden måde at hente brugernavnet fra netværket, og så logge den sammen med, men det er en helt anden sag .....

Helt i orden med mig. Godt det lykkedes til sidst :-)

Fsv angår brugernavn har Dev Ashis denne kode på sin Access hjemmeside. Den virker også glimrende i Excel.

' This code was originally written by Dev Ashish.
' It is not to be altered or distributed,
' except as part of an application.
' You are free to use it in any application,
' provided the copyright notice is left unchanged.
'
' Code Courtesy of
' Dev Ashish
'
Private Declare Function apiGetUserName Lib "advapi32.dll" Alias _
    "GetUserNameA" (ByVal lpBuffer As String, nSize As Long) As Long

Function fOSUserName() As String
' Returns the network login name
Dim lngLen As Long, lngX As Long
Dim strUserName As String
    strUserName = String$(254, 0)
    lngLen = 255
    lngX = apiGetUserName(strUserName, lngLen)
    If (lngX > 0) Then
        fOSUserName = Left$(strUserName, lngLen - 1)
    Else
        fOSUserName = vbNullString
    End If
End Function

Tester jeg lige, hvor mon den brugernavnet?

Måske kan Application.UserName også bruges .......

Har også selv denne liggende:
Det er nok nogenlunde samme kode, som den du viser.

Public Declare Function GetUserName Lib "advapi32.dll" _
                  Alias "GetUserNameA" (ByVal lpBuffer As String, nSize As Long) As Long

                  '#######################################################
                  '###
                  '### Indtast funktionen =ReturnUserName() i en celle
                  '###
                  '#######################################################
                  Function ReturnUserName() As String ' returns the NT Domain User Name

                  Dim rString As String * 255, sLen As Long, tString As String

                  tString = ""
                     
                      On Error Resume Next
                      sLen = GetUserName(rString, 255)
                      sLen = InStr(1, rString, Chr(0))
                     
                      If sLen > 0 Then
                          tString = Left(rString, sLen - 1)
                          Else: tString = rString
                      End If
                     
                      On Error GoTo 0
                     
                      ReturnUserName = UCase(Trim(tString))

End Function

Den laver en Function hvor burgernavner returnes i selve Fucntion navnet. Det kan forholdsvis nemt ændres til en Sub, hvor det lagres i en variabel.

Ligner meget.

De 2 forfattere har vist kigget hinanden over skulderen .....

Mon ikke :-) Håber i hvert fald at du kan brugen noget af det. Jeg må smutte nu - fredagsindkøbene kalder.

Ok, god weekend ....