List alle filer i drev

Hej.

Windows har jo indbygget sådan en funktion.  Skal det indgå i et større projekt eller vil du bare øve dig?  Har du prøvet 'Ekspertens' søgefunktion?  Jeg har lige taget et kig, se f.eks. http://eksperten.dk/spm/437836  Der er mange flere der handler om emnet.

M.v.h. Jørn

Det er mere bare for at øve mig på vb.

Start VB
Smid en knap på din form, der skal hedde "command1"
Smid en listbox på din form, der skal hedde "List1"
Copy-paste nedenstående kode
Under Project > References, tilføjer du 'Micosoft Scripting Runtime"

Koden:

Private Sub Command1_Click()
  Dim fso As Scripting.FileSystemObject
  Set fso = New Scripting.FileSystemObject
  FindFile fso.GetFolder("c:\temp") 'Ret evt. til "c:\", "c:\dokumenter" e.l.
End Sub

Private Sub FindFile(folder As Scripting.folder)
  Dim tmpFolder As Scripting.folder
  Dim tmpFile As Scripting.file
  List1.Clear
  If folder.SubFolders.Count > 0 Then
    For Each tmpFolder In folder.SubFolders
      FindFile tmpFolder  '< proceduren kalder sig selv (dvs. rekursiv)
    Next
  End If
  If folder.Files.Count > 0 Then
    For Each tmpFile In folder.Files
      List1.AddItem tmpFile.Name
    Next
  End If
End Sub


Ovenstående er rekursiv, og du skal nok lige sætte dig ned og prøve at forstå hvad der sker, når sub'ben kalder sig selv igen og igen. Det er ikke helt så enkelt som "almindelige" funktioner og procedurer. Men ovenstående gør præcis hvad du ønsker

UPS - fejl i koden. Slet linien List1.Clear, og flyt den op i den anden sub. Altså:

Private Sub Command1_Click()
  Dim fso As Scripting.FileSystemObject
  Set fso = New Scripting.FileSystemObject
  List1.Clear
  FindFile fso.GetFolder("c:\temp") 'Ret evt. til "c:\", "c:\dokumenter" e.l.
  msgbox "Slut"
End Sub

Private Sub FindFile(folder As Scripting.folder)
  Dim tmpFolder As Scripting.folder
  Dim tmpFile As Scripting.file
  If folder.SubFolders.Count > 0 Then
    For Each tmpFolder In folder.SubFolders
      FindFile tmpFolder  '< proceduren kalder sig selv (dvs. rekursiv)
    Next
  End If
  If folder.Files.Count > 0 Then
    For Each tmpFile In folder.Files
      List1.AddItem tmpFile.Name
    Next
  End If
End Sub

OG skriv nu ikke "C:\temp" i første omgang - det kan tage laaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaang tid at tælle alle filer. Start med et forsøg, f.eks. c:\temp, hvis der ikke er så mange filer der

Alle gode gange tre:

OG skriv nu ikke "C:\" i første omgang - det kan tage laaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaang tid at tælle alle filer. Start med et forsøg, f.eks. c:\temp, hvis der ikke er så mange filer der

Tak for hjælpen